SfinxLite .cshrc

if !($?OSdir) setenv OSdir /strw0/manager

source $OSdir/lib/settings

This defines the location of the Sfinx and SfinxLite systems and reads the default settings. Note that the OSdir setting is system dependent. It is set when SfinxLite is installed, but it can be altered later if necessary.

set history=100

set ignoreeof

set nobeep

set notify

set time=(10 Elapsed:%E,User=%U,System=%S,CPU=%P.)

A few settings for csh and tcsh that might be useful. These are here and not in the system settings because different people have different tastes.

alias prompt 'set prompt="$HOST [\\!] > "'

Define the prompt alias which is used in some other aliases that are included in the default .alias file as examples.

set autolist=ambiguous

set correct=cmd

set prompt2='%R:'

set prompt3="Should't that be '%R' (y|n|e) ? "

set pushdsilent

set who='%n has %a %l from %m at %t'

Some tcsh specific initializations, provided mainly as examples.

alias precmd 'if ($?TITLEPATH) $OSdir/bin/termtitle $HOST \[$cwd\]'

This command can make the host name and current directory appear in the xterm title bar.

bindkey '\e[2~' overwrite-mode

bindkey '\e[5~' history-search-backward

bindkey '\e[6~' history-search-forward

Some keybindings for tcsh : the insert key will toggle overwrite-mode and the PgUp and PgDn keys can be used to search through the command history.

if (-e $HOME/.alias) source $HOME/.alias

If a .alias file exists, it is read now. Users may want to copy the old Sfinx alias file ($OSdir/sfinx/alias) to .alias in order to keep all the old aliases. Most of the old aliases are also included in the template .alias file of SfinxLite.

if (-e $HOME/.settings) source $HOME/.settings

This line takes care of reading the user's .settings for compatibility with the old SFINX system.

package *

These lines, if present, initialize software packages using the package command, which replaces the .packages file. If an .packages file already existed, these entries are created when SfinxLite is installed.